○技能整合类
#showtooltip
/cast [mod:ctrl]元素诅咒
/cast [mod:shift]暗影诅咒
/cast [@mouseover,exists,harm,nodead][]腐蚀术
#showtooltip
/cast [mod:ctrl]诅咒增幅
/cast [mod:shift]语言诅咒
/cast [@mouseover,exists,harm,nodead][]痛苦诅咒
#showtooltip
/cast [mod:ctrl]吸取法力
/cast [mod:shift,@pet]生命通道
/cast [@mouseover,exists,harm,nodead][]吸取生命
#showtooltip
/cast [mod:shift]恐惧嚎叫
/cast [@mouseover,exists,harm,nodead][]恐惧术
#showtooltip
/cast [mod:shift]暗影灼烧
/cast [@mouseover,exists,harm,nodead][]献祭
#showtooltip
/cast [mod:shift]生命分流
/cast [@mouseover,exists,harm,nodead][]暗影箭
说明：以上这些都是一个原理，优先鼠标指向施放最下面的技能，没有指向对当前目标施放；其次按住shift和ctrl施放别的技能
#showtooltip
/cast [mod:shift]地狱烈焰;火焰之雨
说明：按住shift施放地狱烈焰，直接按是火雨
#showtooltip
/cast [mod:alt]防护暗影结界
/cast [mod:ctrl]魔息术
/cast [mod:shift]侦测隐形
/cast 魔甲术
说明：只是简单的把各个BUFF整合在一起，直接按是魔甲术，其他组合键是不同技能
#showtooltip
/cast [nomod]强效治疗石
/cast [mod:shift]制造强效治疗石
#showtooltip
/cast [mod:shift]制造灵魂石
/cast [@mouseover,harm] [harm]放逐术; [@mouseover,help] []灵魂石
说明：上面这两个宏，第一个是shift制造治疗石，直接按使用治疗石；第二个优先鼠标指向，当指向为敌方时为放逐术，友方时实用灵魂石对其绑定。没有鼠标指向就是当前目标，同理地方放逐术，友方灵魂石，在按住shift时是制造灵魂石，无视有没有目标。这个宏的常态(就是没有任何目标，也没有鼠标指向时显示灵魂石的CD和图标)
○宠物控制类
#showtooltip
/petattack
/petattack [target=根基图腾][target=战栗图腾][target=图腾]
/petdefensive
/cast [@mouseover,exists,harm,nodead] [@targettarget,harm] []射击
说明：鼠标指向使用魔杖攻击，同时宝宝切换为防守状态(就是人物被攻击还手的那个)并攻击目标，如果有以上几个图腾则宝宝优先攻击图腾。我把这个宏放在鼠标滚轮上滚键
#showtooltip 感知
/cast [mod:shift]感知
/cast [nocombat]召唤地狱战马
/petfollow
/petpassive
说明：非战斗状态是上马，其次不管在不在战斗状态都是宝宝停止攻击跟随自己并切换为被动状态(就是不会主动攻击的那个)，如果是人类，按住shift则施放感知。我把这个宏放在鼠标滚轮下滚键
#showtooltip
/petattack
/cast [target=player]吞噬魔法
/cast [target=pet]吞噬魔法
/cast [target=mouseover,exists,nodead]吞噬魔法;吞噬魔法
/cast [combat,nopet] [@pet,dead] 恶魔支配
/cast [mod:shift]召唤地狱猎犬
说明：狗驱散的宏，首先你要把驱散自动施放取消，在按这个宏时，优先驱散人物的DEBUFF，其次是宝宝的DEBUFF，再之后是鼠标指向(指向敌方友方都可以，敌方就是驱散他的BUFF，友方驱散DEBUFF)，没有鼠标指向就是对当前选中目标。当你在战斗中且没有宠物或者宠物死亡则施放恶魔支配，同时你再按住shift可以实现顺招狗，在非战斗状态时你可以用这个宏召唤狗，不用担心恶魔支配被使用。
通过试验发现这个宏确实不能用了，目前没有啥特别好的能替换了，所以小伙伴们自己想辙吧goodjob
由于这个宏不能用了，所以我把召唤魅魔放在下面的宏里了
#showtooltip [pet:虚空行者]牺牲;[pet:魅魔]诱惑;[pet:地狱猎犬]法术封锁
/cast [pet:虚空行者,combat]牺牲
/cast [pet:魅魔,@mouseover,harm][]诱惑
/cast [pet:地狱猎犬,@mouseover,harm][]法术封锁
/cast [combat,nopet] [@pet,dead] 恶魔支配
/cast [mod:shift]召唤地狱猎犬
/cast [mod:ctrl]召唤魅魔
说明：多个宠物技能整合，蓝胖时在战斗中使用牺牲，非战斗中误按没事，不会使用的；魅魔时优先鼠标指向诱惑，没有指向就当前目标魅惑；地狱狗时同理魅魔，使用打断；同时跟上一个宏一样当你在战斗中且没有宠物或者宠物死亡则施放恶魔支配，同时你再按住shift可以实现顺招魅魔，在非战斗状态时你可以用这个宏召唤魅魔，不用担心恶魔支配被使用。还有一点，这个宏会根据不同的宝宝换成对应的宝宝技能图标
#showtooltip
/cast [combat,nopet] [@pet,dead] 恶魔支配
/cast [pet:虚空行者]牺牲
/cast 召唤虚空行者
说明：有蓝胖时使用牺牲，没蓝胖且在战斗中且没有宝宝或宝宝死亡，则顺招蓝胖再牺牲。非战斗中你可以使用这个宏召唤蓝胖，不用担心恶魔支配被使用。
#showtooltip
/cast [combat,nopet] [@pet,dead] 恶魔支配
/cast [nomod]召唤虚空行者
/cast [mod:shift]召唤魅魔
/cast [mod:alt]召唤地狱猎犬
说明：当没有BB或者BB死亡，同时处于战斗中时，直接按顺招胖子，shift顺招女人，alt顺招狗。如果不需要战斗中等条件的判断第一行就直接/cast 恶魔支配就可以了
再添加一个代码宏
/run SetCVar("alwaysCompareItems", "1")打开自动装备对比
/console SET chatClassColorOverride "0"聊天框职业着色
/console ShowClassColorInNameplate 1敌方姓名版职业着色
/console ffxGlow 0关闭全屏泛光(关闭晃瞎眼效果)
/console ffxDeath 0关闭死亡效果(死后的灰白世界变成彩色)
/console weatherDensity 0天气效果最低(密密麻麻的大雨变少)
/console rawMouseEnable 1修复鼠标乱飘的问题
/console WorldTextScale 2伤害字体放大，数字可以自行调整，我一般用2
虽然有很多插件都自带了一部分功能，不过还是有一些没有的，所以分享出来。这里面有一些是常驻的，使用一次就行，有的不会常驻，你可以选择做进别的宏里面，自己添加就行了。复制的时候把后面汉字都删了
再有好的宏我还会分享的
2019-11-07 20:24
2019.11.7
因为最近玩了个小德，所以分享点儿小德的宏，有一部分是根据别的大佬的宏改编的
#showtooltip
/cancelform
/cast [mod:shift,@player]回春术; [@mouseover,help] 回春术; [@mouseover,harm] [harm]月火术;[help][noexists]回春术
说明：取消变形形态，优先鼠标指向，其次选中目标，shift自己，友方回春，敌方月火，这个宏会自动改变图标
#showtooltip
/cancelform
/cast [mod:ctrl]自然之握
/cast [mod:shift,@player]激活; [@mouseover,help] 激活; [@mouseover,harm] [harm]纠缠根须;[help][noexists]激活
说明：同上，只不过添加了ctrl施放自然之握
#showtooltip
/cancelform
/cast 自然迅捷
/stopcasting
/cast [@mouseover,help] []治疗之触
说明：取消变形形态，瞬发大触，优先鼠标指向
#showtooltip 重击
/cancelform [noform:1]
/cast [noform:1]熊形态
/cast 重击
说明：按一下切换到熊形态，再按使用重击
#showtooltip
/cancelform [mod:shift]
/cast [form:1]挥击;[form:3]爪击
/cast [mod:shift,@player]治疗之触(等级 4);[noform,@mouseover,help]治疗之触(等级 4);[noform,harm]愤怒;[help][noexists]治疗之触(等级 4)
/startattack [form:1];[form:3,nostealth]
说明：还是优先鼠标指向，友方四级触，敌方愤怒，熊挥击，豹爪击，特别说明的是在熊形态和豹形态的非潜行状态会自动攻击，在任意变形形态按shift会恢复人形并施放四级触
#showtooltip
/cancelform [mod:shift]
/cast [form:1]槌击;[form:3,nocombat,nostealth]潜行;[form:3,nostealth]撕碎;[form:3,stealth]毁灭;[mod:shift,@player]治疗之触;[noform,@mouseover,help]治疗之触;[noform,harm]星火术;[help][noexists]治疗之触
/startattack [form:1];[form:3,nostealth]
说明：同上，只不过在豹形态没潜行会施放潜行，潜行之后施放毁灭
