1吸取灵魂+上马+魅魔隐身术+小鬼火盾
#showtooltip [combat]吸取灵魂(等级 1);迅捷绿色机械陆行鸟
/施放 [btn:2]精龙的蛋
/施放 [btn:1,nocombat]迅捷绿色机械陆行鸟;[noexists]迅捷绿色机械陆行鸟
/施放 [nocombat,pet:魅魔]次级隐形术
/施放 [nocombat,@绯写,pet:小鬼]火焰之盾
/施放 [harm,combat,nochanneling:吸取灵魂]吸取灵魂(等级 1)
战斗中使用1级吸取灵魂且不打断当前的吸取灵魂,战斗外上马。
中间之所以要写无目标上马,是因为有一次在野外打贼的时候,因为我dot还挂在贼身上,但贼已经消失脱战,我明明没在战斗中按宏却上不了马。为了防止卡宏加的那一句。
2手雷宏
#showtooltip
/stopcasting
/petpassive
/use 铁皮手雷
丢手雷,如果位置没安好再按一下可以打断手雷读条重新丢。另外会停止bb攻击,防止提前打晕目标。
3法术石副手宏
#showtooltip 制造特效法术石
/use [harm]17
/equip [equipped:副手物品]特效法术石
/equip [noequipped:副手物品]亚奎门塔斯之魂
/施放 [btn:1.nocombat]制造特效法术石
/施放 [btn:2,nocombat]制造特效火焰石
战斗外左键或单击造法术石,右键造火焰石(虽然用不着)。战斗内点这个宏,如果装备了法术石且目标为敌方,则使用法术石。如果没装备法术石,则装备法术石。如果法术石已被使用,则装备原有的副手武器。也就是所谓的一键法术石宏,肥肠好用。
4魔甲术和防护暗影结界
#showtooltip
/施放 [combat,nomod:shift]防护暗影结界;[combat,mod:shift]魔甲术
/施放 [nocombat,nomod:shift]魔甲术;[nocombat,mod:shift]防护暗影结界
/脚本 SET profanityFilter "0"
/脚本 rawMouseEnable 1
/脚本 MainMenuBarLeftEndCap:Hide()
/脚本 MainMenuBarRightEndCap:Hide()
战斗中防护暗影结界,战斗外魔甲术。战斗中按shift键强制魔甲术,战斗外按shift键强制防护暗影结界。绕晕了没有?因为也有战斗外提前开防护暗影结界和战斗内补魔甲术的情况,但基本是以是否在战斗中为判定标准,故做此宏。后面四句的含义分别为:反文字和谐。反鼠标乱飘。去掉技能栏左右狮鹫。如果使用自定义插件UI的可以删除后面两条。
5饰品宏
#showtooltip
/use 13
#showtooltip
/use 14
这两个分别对应你的上饰品槽和下饰品槽,方便你更换饰品后节省饰品键位。
6宠物技能整合宏(鼠标中键)
#showtooltip
/施放 [nopet]恶魔支配
/施放 [pet:虚空行者]恶魔牺牲
/施放 [pet:虚空行者]牺牲
/施放 [pet:魅魔,@mouseover,harm][]诱惑
/施放 [pet:地狱猎犬,harm]法术封锁
/施放 [pet:地狱猎犬,help]吞噬魔法
/petpassive [pet:小鬼]
/petstay [pet:小鬼]
/petstay [mod:shift]
虽然这里面有很多无用的宠物名称判定(删掉也不影响宏),但是为了自己看着舒服我还是加上了。
解释一下这个宏的作用:
无bb时瞬招;
bb为蓝胖则一键双牺牲;
bb为魅魔则优先诱惑鼠标指向的敌人,若无鼠标指向则诱惑目标;
目标为敌对,则地狱犬使用法术封锁。目标为友方,则地狱犬使用吞噬魔法;
bb为小鬼,则定小鬼在原地;
按住shift键,则无论宠物是什么,都定在原地。
7宠物进攻打图腾宏(鼠标前滚轮)
#showtooltip
/petdefensive
/petattack
/petattack [@战栗图腾] [@图腾]
/petattack [@风怒图腾] [@图腾]
/petattack [@地缚图腾] [@图腾]
/petattack [@根基图腾] [@图腾]
/petattack [@灼热图腾] [@图腾]
/施放 折磨
/施放 剧痛鞭笞
/petautocaston 火焰箭
/施放 [@mouseover,help] [help][@绯写][]吞噬魔法
宠物攻击目标,优先打图腾。魅魔抽鞭子,蓝胖单体嘲讽,小鬼开自动火焰箭。狗的话,优先吞噬鼠标指向友方身上的魔法,其次吞噬目标友方身上的魔法,其次吞噬你身上的魔法(注意改成自己ID),其次吞噬目标身上的魔法。这个宏要和我其他的宠物宏一起看才能发挥全部功效。
8宠物被动跟随宏(鼠标后滚轮)
#showtooltip
/petpassive
/petfollow
/stopmacro [mounted]
/petautocastoff 火焰箭
/施放 [nocombat,pet]黑暗契约
宠物无脑被动+跟随,小鬼关掉自动火焰箭,若不在战斗中则使用黑暗契约(练级中滚着滚轮吸bb蓝很实用)。
9宠物解散+招小鬼宏
#showtooltip [nopet]召唤小鬼;
/施放 [nopet]召唤小鬼
/stopmacro [nopet]
/script PetDismiss ()
没bb召小鬼,有bb解散bb。刷厄运东的时候挺常用的!这里注意一点,如果你用宏绑定的火焰之雨,要加上火雨等级,不然你刷厄运东奴役萨特的时候会卡宏而放不出火雨……
10根据团本战场判定的高级/1级鲁莽诅咒宏+绑定了坐下的动作
#showtooltip [mod:ctrl][group:raid]鲁莽诅咒;鲁莽诅咒(等级 1)
/施放 [mod:ctrl]鲁莽诅咒
/施放 [nomod,nogroup:raid]鲁莽诅咒(等级 1);鲁莽诅咒
/stopmacro [harm]
/stopmacro [combat]
/sit
团本中满级鲁莽,平时1级鲁莽,按ctrl强制满级鲁莽。目标不为敌人且不在战斗中,按该宏可以坐下。
11疲劳诅咒+诅咒增幅
#showtooltip [nomod]疲劳诅咒;诅咒增幅
/施放 诅咒增幅
/施放 疲劳诅咒
一键上强化的疲劳诅咒,诅咒增幅没CD则直接上疲劳诅咒。
按住shift、ctrl和alt中任意一个键,可以看诅咒增幅的CD时间。
12恐惧+恐惧嚎叫+bb打战栗
#showtooltip [mod:ctrl]恐惧嚎叫;恐惧术
/施放 [mod:ctrl][noexists][help]恐惧嚎叫
/施放 [harm]恐惧术
/stopmacro [noharm]
/p 正在恐惧紫色 [%t]
/脚本 if(GetRaidTargetIndex("target")~=3)then SetRaidTarget("target",3);end
/petattack [@战栗图腾] [@图腾]
老宏新功能,绑了个bb打战栗。ctrl键,无目标或目标为友方,则群恐(用来抓贼)。有目标则恐惧目标,并标记紫色+喊话。
13狗自动吞噬魔法宏(多线打法师必备)
#showtooltip
/施放 [nopet]召唤地狱猎犬
/施放 吞噬魔法
/施放 火焰之盾
/petautocaston [harm,combat]吞噬魔法
/petautocastoff [nocombat]吞噬魔法
没狗召狗,bb为狗对目标使用吞噬魔法。bb为小鬼对目标使用火焰之盾。
众所周知荆棘术和火焰之盾冲突,团本火盾可以给那几个喜欢ot的狂暴战和盗贼上一下。
重中之重:当目标为敌人且在战斗中时,开启狗自动吞噬魔法。(挂狗)
不在战斗中,则关闭自动吞噬魔法。
为什么要这么用。一个冰甲法师过来冰环你,你如果带狗开了自动吞噬魔法,可能它会去吃冰甲/法术抑制,而你被冰环在原地,吃强化冰箭吹风被打个措手不及……
此时如果先配合下面的宏,先把自己的debuff吃了,再开启自动让它去咬法师,那就是轻松自在了。狗基本就只需要开局的时候控一下吃buff,打断肯定自己手动。
14宠物技能对己宏
#showtooltip
/施放 [nopet]召唤魅魔
/施放 [@绯写,pet:地狱猎犬]吞噬魔法
/施放 [pet:虚空行者]受难
/施放 [combat,pet:魅魔]安抚之吻
/施放 [nocombat,pet:魅魔]次级隐形术
/施放 [harm,@targettarget][@绯写]火焰之盾
没bb召魅魔,bb为狗则强制吃自身debuff,bb为蓝胖则放群嘲,bb为魅魔则安抚之吻,战斗外则隐形。bb为小鬼,则优先对敌人的目标上火盾,否则给自己上火盾。记得改成自己的角色id。