1.非常基础的饰品玩具宏
——————————————————
#showtooltip
/use [mod:ctrl]17;[mod:alt]8;13
——————————————————
[评论]ctrl使用副手，alt使用鞋子，直接按使用第一格饰品。
没啥技术含量，就是个简单的按键整合宏。
2.冰箭以及乱七八糟宏
——————————————————
#showtooltip
/cancelAura 寒冰屏障
/dismount
/cast [mod:ctrl,@mouseover,help][mod:alt,@player]解除次级诅咒;[mod:ctrl,@mouseOver,harm,nodead][mod:ctrl,harm]变形术;[mod:shift,harm]寒冰箭(等级 1);[harm] [@targettarget,harm] [harm]寒冰箭; [@cursor] 暴风雪(等级 1)
——————————————————
[评价]这个键我用的是最顺手好用的Q键，自然是要好好安排的。
取消冰箱，下马。
ctrl+宏：指向为友方解诅咒，指向敌方羊他，无指向则羊当前目标。
alt+宏：对自己使用解除诅咒。
shift+宏：一级寒冰箭。
正常按则为冰箭，冰箭的目标包括队友的目标和当前目标。
更新一条：如以上技能都没有目标，则对鼠标指向区域下一级暴风雪，不用选框秒下！抓贼神器<特别感谢@謎戀双双 提供的cursor宏，好东西给你点赞！>
3.闪现和反制整合宏
——————————————————
#showtooltip
/dismount [nomod]
/cancelAura 寒冰屏障
/cancelAura 逃跑
/equip [mod:shift]末日颅骨
/cast [mod:shift]17;[mod:alt,@focus][mod:ctrl,@mouseover,harm,nodead][mod:ctrl] 法术反制;闪现术
——————————————————
[评论]取消冰箱，取消末日颅骨
shift+宏：装备末日颅骨，使用副手
alt+宏：反制焦点(怀旧服目前没有焦点，这条白瞎了)
ctrl+宏：反制鼠标指向目标，无指向目标反制当前目标
直接按：闪现
闪现反制什么的很多人喜欢加个打断施法，我就不加了方向盘小动一步是一样的，而打断施法宏很多时候会打断我预判能放出来的技能，因为它判定太快了，比我们人的神经弧快，很容易打乱我的节奏。这里并不推荐打断施法宏。
4.吹风和一级吹风
——————————————————
#showtooltip
/dismount
/cast [mod]冰锥术(等级 1);冰锥术
——————————————————
[评论]这就是个最基础的整合宏，功能键按住的时候放一级吹风，平时满级吹风。
宏不能判断你多少蓝放不同的技能，所以这个宏的最大意义就是告诉你，根据你蓝量buff放技能什么的，宏也做不到啊！
Ps.功能键是只ctrl、alt和shift键，这里不指定按任意功能键都生效。
5.冰环宏
——————————————————
#showtooltip
/dismount
/cancelaura 寒冰屏障
/cast [mod:alt]被遗忘者的意志 ;[mod:ctrl]冲击波
/castsequence reset=2 冰霜新星(等级 1),冰锥术
——————————————————
[评论]惯例二连：下马，出冰箱。
alt+宏：亡灵意志
ctrl+宏：冲击波
直接按：一级冰环，两秒之内再按是吹风，不按则回到冰环循环。
这个我单独解释一下，一个骚气的pvp法师，冰环吹风是我最常用的连招。这么写是为了抢公**光速素质二连，兵贵神速嘛。
6.宝石宏
——————————————————
#showtooltip
/use [combat][mod:alt]法力红宝石
/use [combat][mod:alt]法力黄水晶
/use [combat][mod:alt]法力翡翠
/use [combat][mod:alt]法力玛瑙
/use [combat][mod:alt]5
/castsequence [nocombat,nomod] reset=30 制造魔法红宝石,制造魔法黄水晶,制造魔法翡翠,制造魔法玛瑙
——————————————————
[评论]脱战按做宝石，从大到小，30秒不做就回到做红宝石循环
战斗中按是吃宝石，从大到小，有大法师买一送一。
如果你一定要脱战吃，没问题按ALT强行吃，你是爸爸你说了算。
>>>特别说明一下，这个宏是从目前最大等级的宝石做起的，如果你还没学到要把相应的等级的制造去掉才能用，不然就做不了宝石。
满级太久疏忽了，感谢@神的七十亿个名字 小伙伴的提醒。
下面一些很无聊的按键整合宏我就不放了，接着写。
7.冰箱和开甲宏
——————————————————
#showtooltip
/dismount
/cancelaura 寒冰屏障
/cast [mod:alt,button:2]魔甲术;[mod:ctrl] 法力护盾
/castsequence [mod:alt] reset=1200 冰甲术,魔甲术
/stopmacro [mod]
/castsequence reset=100 寒冰屏障,急速冷却
——————————————————
[评论]惯例下马出冰箱。直接按：冰箱，100秒内再则是极冷，100秒不按回到冰箱循环，这个是为了防贼双盲你冰箱出来来不及按极冷被贼吊起来打。
alt+宏：冰甲，再按法甲，20分钟不按重置到冰甲循环。如果你想直接开法甲，没问题，按住alt右键点击你说了算。
ctrl+宏：法力护盾
8.极冷冰盾吃喝魔杖宏
——————————————————
#showtooltip
/dismount
/cancelaura 寒冰屏障
/cast [mod:alt] 急速冷却;[mod:ctrl]寒冰护体;[nomod,combat]射击
/castsequence [nomod] reset=10 魔法晶水,魔法甜面包
——————————————————
[评论]听起来很复杂是吧，其实却是不很简单……
正常按：惯例先下马出冰箱。脱战时候是喝水，按两下再吃面包，十秒不按回到喝水循环；战斗中扔魔杖，这里你想绷带也是可以的改一改的事。
alt+宏：极冷
ctrl+宏：寒冰护体
极冷不建议直接放在很常用的键位，因为我很容易失手直接开了。所以说人才是宏的爸爸，这么魔鬼的键位安排还不是得听我的？
Ps.补充一下：这个版本用cast代替use宏有时候会出现不能喝水的问题，但只要你包里有水有面包，/RL一下就好了
9.灼烧抑制宏
——————————————————
#showtooltip
/观察 [help,nomod]
/stopmacro [help,nomod]
/cast [mod:alt,@player,combat]魔法抑制(等级 1);[mod:alt,@mouseover,help,nodead][mod:alt,@player]魔法抑制;灼烧
——————————————————
[评论]整合向
点队友按下目标为观察，一键偷窥。
alt+宏战斗中补一级抑制(耗蓝少防驱)，指向优先然后自己。脱战补满级抑制，指向>自己。
非友方目标直接按是灼烧。
这个宏我一样做法的还有缓落火冲宏，增效火球宏，一级火球飞弹宏……别问我增效有啥用，强迫症的习惯你不懂。
10.换装备宏
——————————————————
#showtooltip
/equipslot 13 巴罗夫管家铃
/equipslot [mod] 13 烈焰短笛
/equipslot 13 石楠之环
——————————————————
[评论]第一格饰品管家铃和石楠换来换去，这个适合拍死公主往地精的路上用。你喜欢换啥都行改一改就能用。
功能键+宏是换烈焰短笛，我除了喜欢打架还喜欢搞怪……
11.究极抢怪宏
——————————————————
#showtooltip
/cleartarget
/targetneartarget
/cast 攻击
/startattack
——————————————————
[评论]原理三步走：清除目标，选定最近目标，砍他。这个宏适合知道刷怪点并且旁边有xd和sm准备抢怪的时候狂按……玩过贼的朋友肯定知道抓贼宏，这个宏是一个原理的。
12.团战可以输，xx必须死宏
——————————————————
#showtooltip
/cleartarget
/tar 杰德
/tar 纳克
/tar [dead][noexists]弗
/tar [dead][noexists]库
/stopcasting [harm,nodead]
/cast [harm,nodead] 火焰冲击
/targetlasttarget [noexists][dead]
/cast [noharm]钓鱼
——————————————————
[评论]集找怪抢怪转火一体的宏。
1.转目标：清除目标，寻找杰德，寻找纳克
2.动作：目标为敌对单位并且非死亡直接火冲，这个也是个火冲抢特定怪宏，目标不存在或者死亡则选择上一个目标。你按了这个宏没找到怪丝毫不影响你当前状态，不会因为按了火冲自动下马(因为没有找到活着的敌对目标根本不会火冲)，你不仔细听换目标的声音甚至不知道自己按没按这个宏……
最后当前没有敌对目标则钓鱼，省一个钓鱼键位……我有时候还是个休闲玩家………………
13.一键6专业宏
——————————————————
#showtooltip
/cast [mod,button:2]烹饪;[mod]急救;[button:2]侏儒工程学;附魔
——————————————————
直接按是附魔，功能键按是急救，右键按是侏儒工程，功能键+右键是烹饪。
功能键再细分是可以实现最多8专业的。我没学那么多就先这样吧
基本就更这些了，很困睡了下次再见。
19.11.26编辑：
——————————————————
关于奥强短暂气定三开+冰箭宏自动取消奥强的解决方案。
#showtooltip
/cast !奥术强化
/use 短暂能量护符
/cast 狂暴
/cast 气定神闲
/cast 寒冰箭
有人反映{/cast !奥术强化}没有用，多按还是会取消奥强，我虽然没有洗奥强但是也测试过{/cast !寒冰屏障}是可以防出冰箱的，然而{/cast !射击}却不能防取消魔杖。
所以附一个不完美的解决方案：
#showtooltip 寒冰箭
/castsequence reset=10 奥术强化,null
/cast 短暂能量护符
/cast 气定神闲
/cast 寒冰箭
这个宏可以模拟出来，按了宏之后要等10秒不按以后才能再回到奥强。也就是说你一直抽风按的话永远不会按第二次奥强，缺点就是下次奥强之前这个宏要有个停按这个宏10秒的间隔。
不按重置的时间{reset=10}可以自行更改，举个例子，如果你是用来pve的可以改成2秒，缺点就是奥强期间要猛按不能停超过两秒的时间。
