键位/宏思路:
(1) 技能按特性放在不同位置:
术士主体技能用键盘控制[1-5][Q-T][F-G][Z-V],宝宝技能及饰品工程用鼠标控制[滚轮和侧键];
读条技能[1-5],和常用诅咒[alt+1-5] 放一起站定不用按asdw移动;瞬发技能[ER,FG]放在asdw周围,方便移动的时候施放。其中[E]死缠,|R]灼烧比较近,因为都是瞬发爆发技能。
(2) 鼠标和键位尽量符合逻辑:
多技能按属性分组绑在一个宏里[吸血给血,抽蓝抽灵魂,感知与侦测,恶魔与奴役,暗影盾和魔甲]且能自动更换为不同技能图标,有些技能尽管性质难以归类但是本着减少一个按键的原则,也尽量组合起来,如魔息和眼睛。
BB控制宏能自动实别所有宝宝(>40级)的所有核心技能,尽量符合逻辑,且能自动更换为不同的宠物技能图标。比如
1)鼠标滚轮上推,代表进攻。胖子折磨,mm鞭子,狗吃掉魔法,优先鼠标指向吃掉敌人buff,其次友方buff;同时按下shift加鼠标滚轮上推,为感知模式,人类感知+隐形侦测。
2)鼠标滚轮下推,代表防御。胖子群嘲,mm安抚,狗吃掉本人(玩家)的自身有害buff,小鬼对目标目标上盾;战斗外,蓝胖回血,mm隐身。同时按下shift加鼠标滚轮下推,为逃跑模式,放弃打任何怪,宝宝和人一起跑,强制被动+跟随。
3)鼠标滚轮中键,即往下按,代表核心控制。蓝胖牺牲,mm诱惑,狗打断,没有bb就恶魔支配,准备瞬召;同时按下shift加鼠标中键,召唤狗;按下cirl加鼠标中键,召唤mm;按下alt加鼠标中键,召唤胖子,配合顺招。
4)鼠标侧键1,绑定工程道具,如带光标指向的(cursor)的铁皮手雷;鼠标侧键2,绑定炼金道具。
按键分配:
动作条1:主要法术(按下shift使用第二技能,战斗外使用生活技能)
[1] 腐蚀术+“制作治疗石并交易”
[2] 痛苦诅咒+“制作灵魂石并绑定”
[3] 暗影箭/火焰之雨+“地精起搏器复活友方”
[4] 魔棒/地狱烈焰+“跟随友方”
[5] 灼热之痛+“查看友方装备”
[Q] 吸取生命/生命通道
[E] 死亡缠绕/可配备饰品强化伤害
[F] 生命分流/基尔罗格之眼
[Z] 疾跑道具(灵巧秒表/地精火箭鞋)
[X] 感知恶魔/奴役恶魔
[C] 放逐术/魔息术
[V] 恐惧术/恐惧嚎叫
动作条2:诅咒与其他主要法术
[Alt+1] 祭献+索敌
[Alt+2] 语言诅咒
[Alt+3] 虚弱诅咒
[Alt+4] 鲁莽诅咒
[Alt+5] 元素诅咒
|R] 暗影灼烧
[T] 吸取灵魂/吸取法力+“交易友方”
[G] 魔甲术/防护暗影结界
动作条3:宠物控制、工程道具与饰品
[鼠标上滚轮] BB进攻模式
[鼠标下滚轮] BB防御模式
[鼠标中滚轮] BB核心控制
[shift+鼠标上滚轮] 感知/侦测隐形
[shift+鼠标下滚轮] BB跟随模式
[鼠标侧键] 铁皮炸弹
动作条4-5:吃喝生活系,未绑定按键
[] 找人宏
[] 坐骑宏
[] 一键吃宏
[] 一键喝宏
[] 治疗石宏
[] 副本重置宏
输出手法:
平时练级打怪习惯先[1]腐蚀术 => [2]痛苦诅咒 => [3]暗影箭促发爆发Buff/ 如果有一堆怪此时按下shift,暗影箭会自动变成 [4] 火焰之雨 => 自己习惯1-3发暗影之后就开始丢 [4] 魔杖 或者 [5] 灼热之痛(cd1.5秒很舒服,高仇恨技能,队友濒死时吸引怪,大义凛然~)
此外,会根据特殊情况施加不同诅咒,[alt+1] 祭献,[alt+2] 语言给法系 ,[alt+3] 虚弱给物理 ,[alt+4] 鲁莽处理逃跑小怪,[alt+5] 元素下本工具人。
常用的顺发技能和引导技能都放在asdw移动按键边上根据情况使用。[E]死亡缠绕,好了就用,野外可以留着防身;|R]暗灼,怪快没血了用,瞬发高伤害,4秒内杀死怪返回一个片;[T]没片了吸一吸;[Q]给自己(不按shift)或者宝宝(按shift)加血,视情况使用。[ZXC]这一排是逃跑加速,恐惧/群恐惧,以及放逐,视情况使用
宏列表:
总体说明:所有宏都绑定了鼠标指向;M代表Main,BB代表pet一般放在职业专有宏里(16格),C代表common,一般放在通用宏里(36格)。
大多数宏都用shift做条件,主要因为手小平时用笔记本键盘也小,采用shift小拇指,space(和alt)大拇指,asdw其余三指比较舒服。alt1-5 主要做上诅咒用,Mac OS系统command即alt。。
[1] BB-控制
[1-1] BB-控制模式/战斗瞬召
#showtooltip [pet:虚空行者]牺牲;[pet:魅魔]诱惑;[pet:地狱猎犬]法术封锁;[nopet]恶魔支配
/施放 [pet:虚空行者,combat]牺牲
/施放 [pet:魅魔,@mouseover,harm][]诱惑
/施放 [pet:地狱猎犬,@mouseover,harm][]法术封锁
/施放 [combat,nopet] [@pet,dead] 恶魔支配
/施放 [mod:shift]召唤地狱猎犬
/施放 [mod:ctrl]召唤魅魔
/施放 [mod:alt]召唤虚空行者
说明:
习惯绑定中滚轮,按下蓝胖牺牲(只有战斗中才会牺牲,非战斗按下没事,防止错按),mm诱惑,狗打断,没有bb就恶魔支配(支配是核心pvp技能,默认只有战斗下才会开启),准备瞬召;
另外按下shift加鼠标中键,召唤狗;按下cirl加鼠标中键,召唤mm;按下alt加鼠标中键,召唤胖子;小鬼不单独设置,另外有宏操控。
[1-2] BB-进攻模式/驱散敌方
#showtooltip [pet:虚空行者]折磨;[pet:魅魔]剧痛鞭笞;[pet:地狱猎犬]吞噬魔法;[pet:小鬼][]火焰箭
/targetenemy [help][dead][noexists]
/petdefensive
/petattack [harm]
/施放 [pet:虚空行者]折磨
/施放 [@mouseover,pet:魅魔] [@target,pet:魅魔] 诱惑
/施放 [@mouseover,harm,pet:地狱猎犬][help,pet:地狱猎犬][]吞噬魔法
说明: BB进攻系列,习惯鼠标滚轮往上一推,胖子折磨,mm鞭子,狗吃掉魔法,优先鼠标指向吃掉敌人buff,其次友方buff。
[1-3] BB-防守模式/强制对我
#showtooltip [pet:虚空行者]受难;[pet:魅魔]安抚之吻;[pet:地狱猎犬]吞噬魔法;[pet:小鬼][]火焰之盾
/petdefensive
/施放 [@targettarget,pet:小鬼] 火焰之盾
/施放 [@player,pet:地狱猎犬] 吞噬魔法
/施放 [combat,pet:虚空行者]受难
/施放 [nocombat,pet:虚空行者]吞噬暗影
/施放 [combat,pet:魅魔]安抚之吻
/施放 [nocombat,pet:魅魔]次级隐形术
说明:
BB防守系列,习惯鼠标滚轮往下一推,胖子群嘲,mm安抚,狗吃掉本人(玩家)的自身有害buff,小鬼对目标目标上盾。战斗外,蓝胖回血,mm隐身。
[1-4] BB-跟随模式
#showtooltip
/petpassive
/petfollow
说明: BB无条件放弃打任何怪,跟随自己跑路。
[1-5] BB-召唤小鬼
#showtooltip [nopet]召唤小鬼
/施放 [nopet]召唤小鬼
/stopmacro [nopet]
/script PetDismiss ()
说明: 按一下召唤小鬼,再按一下解散
[1-6] BB-牺牲瞬召
#showtooltip 恶魔牺牲
/施放 牺牲
/施放 恶魔支配
/施放 召唤虚空行者
说明:
牺牲宝宝并瞬召一个;
在这里需要说明 /cast /use /施放 效果完全一致,区别在于cast 是2字符,施放是1字符。
[1-7] BB-蓝胖双牺牲
#showtooltip 恶魔牺牲
/施放 恶魔牺牲
/施放 牺牲
说明:
这个技能我一般手点,作为保命大招,因为同时有蓝胖盾+4秒3%回血buff,有效节省一个片。
另外一个技巧是胖子牺牲后可以用地精起搏器强行救活,这样既有BB,又有Buff。嘘~
[2] 主动作条
[2-1] M-腐蚀术
#showtooltip 腐蚀术
/施放 [mod:shift]制造强效治疗石
/施放 [@mouseover,harm] [@target,harm,nodead] 腐蚀术
/施放 [harm,dead][nocombat]制造强效治疗石
/petattack [nocombat]
/脚本 UIErrorsFrame:Clear()
说明:
战斗中腐蚀术,宠物配合攻击;
战斗外制造治疗石,shift按下强制任何环境下做治疗石;
最后一行命令是防止报错提示音(我不能攻击那个目标)。
[2-2] M-痛苦诅咒
#showtooltip 痛苦诅咒
/施放 [combat]诅咒增幅
/施放 [mod:shift]制造强效灵魂石
/施放 [@mouseover,harm] [@target,harm,nodead] 痛苦诅咒
/施放 [harm,dead][nocombat,noexists]制造强效灵魂石
/use [harm,dead][noexists]强效灵魂石; [help,nodead]强效灵魂石
/petattack [nocombat]
/脚本 UIErrorsFrame:Clear()
说明:
战斗中诅咒增幅,痛苦诅咒,宠物配合攻击;
战斗外按一下制造灵魂石头,按两下,目标自己绑自己,目标队友绑队友。
最后一行命令是防止报错提示音(我不能攻击那个目标)。
[2-3] M-暗影箭
#showtooltip [nomod:shift]暗影箭;火焰之雨
/施放 [mod:shift]火焰之雨
/equip [harm,equipped:鱼竿]催眠之刃
/equip [harm,equipped:鱼竿]达奥拉赫宝珠
/施放 [equipped:鱼竿]钓鱼
/施放 [harm,nomod]暗影箭
/施放 [@mouseover,nocombat,help,dead][@target,nocombat,help,dead]地精起搏器
说明:
战斗中暗影箭,shift按下火焰之雨;
装备钓竿则钓鱼,装备钓竿且目标为敌人则切换为战斗武器。
战斗外对鼠标指向或选中的尸体使用起搏器。
[2-4] M-暗影灼烧
#showtooltip 暗影灼烧
/施放 [@mouseover,harm,combat] [@target,harm,nodead] 暗影灼烧
说明: 鼠标指向暗影灼烧。
[2-5] M-灼热之痛
#showtooltip 灼热之痛
/施放 [@mouseover,combat,harm] [@target,harm,nodead] 灼热之痛
/petattack [nocombat]
/stopmacro [nohelp,combat]
/ins
说明: 鼠标指向灼热之痛;战斗外按下看装备。
[2-6] M-吸取生命/通道
#showtooltip [nomod:shift]吸取生命;生命通道
/施放 [mod:shift,@pet,nochanneling]生命通道
/施放 [nomod,nochanneling]吸取生命
说明: 按下吸血,shift按下给BB加血。
[2-7] M-死亡缠绕
#showtooltip 死亡缠绕
/stopcasting
/脚本 local s,d,_,t=GetSpellCooldown("死亡缠绕")t=s==0 and"对%t施放死亡缠绕"or"[死亡缠绕]还有"..ceil(s+d-GetTime()).."秒冷却"SendChatMessage(t,"party")
/施放 死亡缠绕
/use 13
说明: 按下死亡缠绕并喊话提醒队友不要打断恐惧,同时使用饰品13(如果不在冷却)。
[2-8] M-生命分流/眼睛
#showtooltip [nomod:shift]生命分流;基尔罗格之眼
/施放 [mod:shift]基尔罗格之眼
/施放 [nomod]生命分流
说明: 按下血换蓝,shift按下召唤眼睛。