感谢前辈们的经验总结,本人只是整理,并非原创
1, "#showtooltip+技能名字" 这个命令是使宏图标显示出技能的冷却,如果装有Cooldown显示类插件,可以以此命令实现宏图标显示技能冷却. 同时鼠标移动带该宏图标上不会像过去一样只显示宏名字,而是显示"技能名字"这个你所输入的技能的说明.
2, "/stopcasting" 同1.12版本的"/script SpellStopCasting();"效果一样,只是旧版的不好用了,换个方式
变羊宏
组队变羊
--------------------------------
/script if UnitSex("target")==1 then g="female " else g="male " end;s="Sheeping "..g..UnitLevel("target").." %T";c="say";if GetNumRaidMembers()>0 then c="raid" elseif GetNumPartyMembers()>0 then c="party" end;SendChatMessage(s,c)
/cast Polymorph
--------------------------------
raid变羊
--------------------------------
/cast detect magic
/focus
/script SetRaidTarget("focus", 1)
/script if UnitSex("target")==1 then g="female " else g="male " end;s="I?m going to sheep a "..g..UnitLevel("target").." %T";c="Party";if GetNumRaidMembers()>0 then c="raid" end;SendChatMessage(s,c)
--------------------------------
注：这两个宏能告之你的队友和队伍你施法目标的性别，等级，如果你不在队伍中，那仅仅施放变羊术，后面那个在施法前还放上了法术侦测，改良一下在pvp时对付萨满有很好的效果。
竞技场变羊宏
--------------------------------
#showtooltip 变形术
/focus [target=focus, noexists] [target=focus, dead] [target=focus, help]
/stopmacro [target=focus, noexists]
/cast [modifier:shift,target=focus,exists] 变形术(等级 1); 变形术(等级 1)
/petfollow
--------------------------------
对当前目标变羊.如果当前无焦点目标则设置该目标为焦点,在有焦点的状态下对其他非焦点目标变羊不改变当前焦点.除非焦点目标死亡/消失.按Shift对焦点目标变羊. 最后一行意思为,变羊的同时设置水元素为跟随,请根据个人情况使用.
智能变羊宏2
--------------------------------
#showtooltip 变形术(等级 1)
/Cast [target=focus,harm,exists,modifier:shift]变形术(等级 1); [target=mouseover, harm, exists]变形术(等级 1); 变形术(等级 1)
/focus [target=focus,noexists] [target=focus,dead] target
--------------------------------
功能：按shift，并且当前已经设置的焦点目标，则强制把你的焦点目标变羊。如果没按shift，并且你的鼠标当前指向敌对目标，则将你鼠标指向的目标变羊，否则将你当前目标变羊。如果你之前没有设置焦点目标，或者焦点目标已经死亡，则将你当前目标设置为焦点目标。
随机变形目标(动物园术)
--------------------------------
#showtooltip 变形术
/castrandom 变形术,变形术：猪,变形术：龟
--------------------------------
随机施放三种变形术,很娱乐
生活类宏
一键厨师吃喝宏
--------------------------------
#showtooltip 魔法肉桂面包
/use [nomodifier:alt,button:1] 魔法晶水
/use [nomodifier:alt,button:2] 魔法肉桂面包
/cast [modifier:alt, button:1] 造水术(等级 7)
/cast [modifier:alt,button:2] 造食术(等级 7)
--------------------------------
鼠左键喝水,鼠右键吃面包,按住alt 鼠左键 做水, 按住alt 鼠右键 做面包
一键做吃法力石宏
--------------------------------
#showtooltip 法力红宝石
/use [nomodifier:alt] 法力红宝石
/use [nomodifier:alt] 法力黄水晶
/use [nomodifier:alt] 法力翡翠
/use [nomodifier:alt] 法力玛瑙
/cast [modifier:alt, button:1] 制造魔法红宝石
/cast [modifier:alt,button:2] 制造魔法黄水晶
--------------------------------
鼠左键吃红宝石,黄水晶,按住alt 鼠左键 做法力红宝石, 按住alt 鼠右键 做法力黄水晶
从大到小按顺序吃蓝石宏:
--------------------------------
#showtooltip 法力红宝石
/use 法力红宝石
/use 法力黄水晶
/use 法力翡翠
/use 法力玛瑙
--------------------------------
(吃其他东西也同理/use 物品名称)
根据场合使用绷带宏
--------------------------
/use 战歌峡谷符文布绷带
/use 污染者的符文布绷带
/USE 奥特兰克厚符文布绷带
/USE 厚符文布绷带
---------------------------
不用再换绷带了.一键搞定.
重置副本
--------------------------------
/invite 玩家名称
/script LeaveParty()
--------------------------------
刷副本爱好者的最爱
协助目标宏
--------------------------------
/cleartarget
/assist [player name]
--------------------------------
清除现在的目标并选中你协助对象的目标,有利于统一RAID,PVP统一目标
BUFF类宏
一键智能魔法增/减幅
--------------------------------
/cast [button:2, party] 魔法增效; [button:2, target=player] 魔法增效; [party] 魔法抑制; [target=player] 魔法抑制
--------------------------------
注：左键魔法抑制，右键强化，如果目标为队友，将buff他，否则buff自己。
智能冰甲
--------------------------------
/cast [combat]冰甲术(等级 1);冰甲术
--------------------------------
战斗外补顶级冰甲，战斗中补1级冰甲，竞技场里面被集火的时候，多一个buff也是多一份存活的希望，所以需要补冰甲，但是为了省蓝，所以补1级最合算。1级冰甲少300多护甲，但是附带的减速和刺骨效果是很重要的。
强殖装甲
--------------------------------
/cast [modifier:alt] 冰甲术; [button:2] 熔甲术; 魔甲术
--------------------------------
注：左键魔甲，右键熔岩护甲，alt+点击为冰甲
连续技宏
奥术冲击灼烧宏
--------------------------------
/castsequence reset=7 奥术冲击, 灼烧, 灼烧, 灼烧
--------------------------------
注：出于魔法使用效率考虑，连按这个宏将施放三次灼烧，然后一个奥术冲击，如果7秒内没使用它，将重置为奥术冲击起始。奥术冲击的加速施法效果将改变副本中单一的冰弹火球模式，今后和猎人一样，一个合理的输出模式将大大提高你的魔法效率和dps.对某些冰系免疫的怪，这个宏也很有用。
龙息3连招
--------------------------------
#showtooltip 龙息术
/stopcasting
/castsequence reset=20 龙息术, 灼烧, 冲击波
--------------------------------
连续按依次是龙息,灼烧,冲击波.20秒没有使用将重置顺序.
施法类宏
冰枪宏:
--------------------------------
#showtooltip 冰枪术
/cast [target=mouseover,exists] 冰枪术;冰枪术
--------------------------------
优先攻击鼠标指向的目标,否则攻击当前目标
机关枪宏:
--------------------------------
/stopcasting
/cast [target=风怒图腾, harm, exists] 冰枪术
/cast [target=战栗图腾, harm, exists] 冰枪术
/cast [target=地缚图腾, harm, exists] 冰枪术
/cast [target=法力之泉图腾, harm, exists] 冰枪术
/cast [target=法力之潮图腾, harm, exists] 冰枪术
/cast [target=根基图腾, harm, exists] 冰枪术
/cast [target=清毒图腾, harm, exists] 冰枪术
/cast [target=灼热图腾, harm, exists] 冰枪术
/cast [target=mouseover,harm,exists]冰枪术;冰枪术
--------------------------------
自动打图腾，没有指定图腾，就打鼠标指向目标，也没有的话就打当前目标。不会改变当前目标，需要打其他图腾的自己加
瑟银手雷:
--------------------------------
#showtooltip 瑟银手雷
/stopcasting
/use 瑟银手雷
--------------------------------
因为铁皮手雷在更新后对53级以上目标就会有几率失败而对60级的目标几乎是90%以上的失败率所以基本作废了,喜欢投手雷的朋友可以换瑟银玩.
宏同过去的铁皮宏,使用途中按为取消.
闪现宏:
--------------------------------
#showtooltip 闪现术
/stopcasting
/cast 闪现术
--------------------------------
中断当前正在施放的法术直接闪现.
反制宏:
--------------------------------
#showtooltip 法术反制
/stopcasting
/cast [modifier:shift,target=focus,exists] 法术反制; [target=mouseover,exists]法术反制; 法术反制
--------------------------------
按shift反制焦点.不按反制当前.优先对鼠标指向的目标反制.如果鼠标无目标则对当前目标
无视公共冷却开关冰箱宏:
--------------------------------
#showtooltip 寒冰屏障
/stopcasting
/cancelAura 寒冰屏障
/cast 寒冰屏障
--------------------------------
有冰箱则关冰箱,无冰箱则中断施法开冰箱.
条件奥爆宏
--------------------------------
/cast [noharm] 魔爆术(等级 1);魔爆术
--------------------------------
有目标时顶级奥爆.无目标时1级.将[noharm]改为[nocombat]为不在战斗状态使用一级奥爆,反之顶级.
1级暴风雪打消失宏
--------------------------------
#showtooltip 火焰冲击
/stopcasting
/cast [harm]火焰冲击; 暴风雪(等级 1)
--------------------------------
有目标时火焰冲级,没目标时为一级暴风雪
精确目标宏:
--------------------------------
/targetexact 恶魔之链
/cast 灼烧
--------------------------------
精确目标为恶魔之链使用灼烧攻击,其他目标或技能请更换相应名称
护符双开气定炎爆:
--------------------------------
#showtooltip 气定神闲
/stopcasting
/use 14
/cast 奥术强化
/cast 气定神闲
/cast 炎爆术
--------------------------------
如果不用开护符就吧/use 14这行去掉,如果想改成气定冰箭就把"炎爆术"改成"寒冰箭".
冰箭/1级冰箭宏:
--------------------------------
#showtooltip 寒冰箭
/cast [modifier:alt] 寒冰箭(等级 1); 寒冰箭
--------------------------------
同上面的火球宏,直接按满级冰箭,按住Alt按是1级冰箭.如果想把Alt换成别的键请修改[modifier:alt]中的"alt",可以改成ctrl,shift等
当然也可以用同样方法实现火球/1级火球的合并.
Nova宏:
--------------------------------
#showtooltip 冰霜新星(等级 1)
/stopcasting
/cast [nomounted] 冰霜新星(等级 1)
/dismount [mounted]
--------------------------------
不在坐骑上则中断当前正在施放的法术放1级冰环,在坐骑上则下马什么都不做(由于2.0的修改,直接按技能会空中下马并放出技能,习惯Ezdismount的按技能下马再按技能才放的朋友可能不习惯,就可以用这个)
反控制宏
--------------------------------
#showtooltip
/stopcasting
/cast [modifier:alt] 逃脱大师(亡灵意志,石像形态)
/stopmacro [modifier:alt]
/use 13
--------------------------------
13 - 第一个饰品位放徽记, 按下ALT使用种族技能,不按使用徽记
高精神武器唤宏
--------------------------------
#showtooltip 唤醒
/cast 唤醒
/equip 苏醒之杖
/equip [nochanneling:唤醒]庇护法杖
--------------------------------
换醒时装备高精神装备(例:苏醒之杖)当唤醒冷却时按下是换回常规装备(例:庇护法杖)
水元素宏
召唤水元素和水元素攻击宏:
-----------------------------------------
/cast [nopet] 召唤水元素
/stopmacro [target=pettarget, exists]
/petattack
-----------------------------------------
注：点击一次将召唤水元素
再点一次水元素将攻击你的目标，在召唤后的lag时间内重复点击可以让宠物立即进入攻击状态并不会取消第一个水球.
宝宝+远程Nova宏:
--------------------------------
#showtooltip [pet] 冰冻术
#showtooltip [nopet] 召唤水元素
/cast [nopet] 召唤水元素
/click [pet] PetActionButton5
--------------------------------
没有宝宝的情况下图标显示"召唤水元素"技能说明并显示该技能冷却,有宝宝的情况下图标显示宝宝的远程冰环"冰冻术"技能说明及冷却.
在没有宝宝时按下则召唤宝宝,有宝宝是按则施放宝宝的远程冰冻术.
注: 宝宝的Nova在默认宠物技能条的第5格,请不要移动它,如果放到别的格子请自行修改PetActionButton5
这句中"5"为相应的数字.
召唤水元素攻击图腾:
--------------------------------
#showtooltip [nopet] 召唤水元素;[pet] 冰冻术
/cast [nopet] 召唤水元素
/petpassive
/click [pet] PetActionButton5
/target 根基图腾;战栗图腾;地缚图腾
/petattack
--------------------------------
召唤水元素,攻击,并设置被动模式.不想冰环的删除 /click [pet] PetActionButton5
变形时宠物停止攻击
---------------------------------------
/petfollow
/施放 变形术
---------------------------------------------
变目标变羊同时让宝宝停止攻击跟随自己.此宏可单独作为bb跟随命令
其他命令
/petattack 宠物攻击
/petfollow 跟随
/petstay 停留
/petpassive 被动模式
/petdefensive 防御模式
/petaggressive 主动攻击
/petautocaston
/petautocastoff
